Displaying times in asp is quite a fiddly affair. Theres a lot of different ways of displaying ASP dates and times. Using FormatDateTime you can output data as just the date, just the time, a mixture, 24 hour time format, 12 hour time format etc etc. One very useful tip for doing this in projects is to create yourself a little function such as the one found below. This gives you alot of flexibility and scope to easily change formats and display them as you wish.

Our function here, covers one of the most common formatting issues, often seen in forums and blogs. It simply changes any date that is within the past 24 hours to the word 'Today' followed by the time, and replaces anything >24 hours and less than 48< hours with the word 'Yesterday' followed by the time.

Our function is called as follows:

<%
DateString=rs("Timestamp") '--Any date source such as a timestamp from your database data.
Response.write(FriendlyDates(DateString,Session("ID"),0))
%>


<%function FriendlyDates(DateTime,LoggedIn,Format)
    if LoggedIn>0 then   
        DateTime=DateAdd("h",session("Timezone"),DateTime)
        if Format=0 then '//Standard Date + Time unless within the last 48hours.
            if DateDiff("d",DateTime,Date) < 1 then FriendlyDates="Today at "&cStr(FormatDateTime(DateTime,3))
            if DateDiff("d",DateTime,Date) = 1 then FriendlyDates="Yesterday at "&cStr(FormatDateTime(DateTime,3))
            if DateDiff("d",DateTime,Date) > 1 then FriendlyDates=DateTime
        end if
    else
        FriendlyDates=DateTime
    end if
    FriendlyDates="<span class=""smallTimeStd"">"&FriendlyDates&"</span>"
end function
%>

The function again with no scope for timezones or formatting:

<%
DateString=rs("Timestamp") '--Any date source such as a timestamp from your database data.
Response.write(FriendlyDates(DateString))
%>

<%function FriendlyDates(DateTime)
    if DateDiff("d",DateTime,Date) < 1 then FriendlyDates="Today at "&cStr(FormatDateTime(DateTime,3))
    if DateDiff("d",DateTime,Date) = 1 then FriendlyDates="Yesterday at "&cStr(FormatDateTime(DateTime,3))
    if DateDiff("d",DateTime,Date) > 1 then FriendlyDates=DateTime
    FriendlyDates="<span class=""smallTimeStd"">"&FriendlyDates&"</span>"
end function
%>

Theres a few parts to this function that you may not use, but weve left them in just incase you want to patch around it. For example our site stores a session("Timezone") that is an integer between -12 and 12. This is set when a user logs in, and is based off their profile information. This allows us to display times relative to their global location.

The 3rd parameter is passed as a 0. This is purely incase we want to change the format, or add different formatting styles later on.
For example we could add a 'If Format=1 then' where the code never shows the time, and only provides the date. In a chatroom you may want to add an if statement to only show the time.

Our example outputs the time in a span tag with a class. This enables you to add a CSS class so that all your websites dates and times show in exactly the same style.

Thats about it for this quick little article. Hopefully you'll be able to integrate this ASP Date formatting technique into your own work!

Happy programming.
Carl Barnett.

In the past couple of years I, and my colleague, have created several online communities (quite successful ones i might add) and two fairly important parts of these communities are the forums and chatrooms. If you've used online forums/message boards before then you've probably noticed that the majority of them use a swear filter / language filter. Because we didn't use an "Out of the box" forum package for our communities we had to create our own filters using ASP / VBScript. Here is an example of a fairly simple ASP based language filter function:

Function Language_Filter(s)

dim badwordsfilter,badWords,regEx,badword
badwordsfilter="word1,word2,word3,"
badWords = Split(badWordsFilter, ",")
Set regEx = New RegExp
regEx.IgnoreCase = True
regEx.Global = True
For Each badWord In badWords
badWord = Trim(badWord)
regEx.Pattern = "(\s"&badWord&"\s)|(^"&badword&")|(^"&badword&"$)|("&badword&"$)"
regEx.Pattern = "\b"&badWord&"\b"
s = regEx.Replace(s, padBadWordWithAsterisks(badWord))
Next
Language_Filter = s
Set RegEx=Nothing
end function

Bear in mind that this would probably be used after any other "cleaning" of the input text for invalid / dangerous characters. (We will look at that in another post)

Data integrity is one of those tedious, horrible tasks no one really wants to do. After all, when you have a form with 20 fields worth of data coming in from a form post who really wants to check that the email address is properly formatted, or that a telephone doesnt contain any letters or symbols!? Standard methods might have you checking its length isn't 0, or that its a Cint data type, or that it has an @ symbol in the string etc etc...

A quicker, and more manageable option is to stick all these checks into a function and simply call the function with paramaters based on what you're checking for. For example:

submitEmail=False
submitTelephone=False
emailData=request.form("email")
telephoneData=request.form("tel")
if validation_check(emailData,"Email",null,null) then submitEmail=True
if validation_check(telephoneData,"Tel",null,null) then submitTelephone=True

The function that we call our checks against can be found below. It consists of nothing more than a series of if statements that checks against what type of validation you're wanting, and then runs the subsequent regular expression code. We wont go into the ins and outs of regular expressions here, as theyre a rather complex beast and to be honest....you can usually manage without knowing exactly how it works. If you need a regular expression check for a different data format, simply have a quick search on google and you're sure to find what you're after! The function we often use in many of our sites below covers all the usual data types that we check against. If the regular expression pattern is found the function returns True, otherwise it returns False.

Lets take a look at our function: 

Function validation_checks(inputStr, regtype, min, max)
    set reg=new RegExp
    reg.Global=True
    reg.Ignorecase=True
    if regtype="chat" then
        reg.Pattern="\S+?"
    elseif regtype="numerical" then
        reg.Pattern="^\d{"&min&","&max&"}$"
    elseif regtype="alphanumeric" then
        reg.pattern="^[\w ]{"&min&","&max&"}$"
    elseif regtype="usernameorpassword" then
        reg.pattern="^[\w _-]{"&min&","&max&"}$"
    elseif regtype="alpha" then
        reg.pattern="^[a-zA-Z ]{"&min&","&max&"}$"
    elseif regtype="sentence" then
        reg.pattern="^[\w\.\(\)\\\*\\+\?\$,'-_&%""!= ]{"&min&","&max&"}$"
    elseif regtype="email" then
        reg.pattern="^[A-Z0-9._%-]+@[A-Z0-9.-]+\.(?:[A-Z]{2}|com|org|net|biz|info|name|aero|biz|info|jobs|museum|name)$"
    elseif regtype="emailornone" then
        reg.pattern="^([\w-_.]*[\w-_.]@[\w-_]+?[\w-_.]+\.[\w.]{3,})?$"
    elseif regtype="postcode" then
        reg.pattern="^[a-zA-Z]+[a-zA-Z0-9]{1,3}\s[\d]{1}[a-zA-Z]{2}$"
    elseif regtype="phone" then
        reg.pattern="^[\d ]{"&min&","&max&"}$"
    elseif regtype="money" then
        reg.pattern="^[\d]{"&min&","&max&"}\.?[\d]{0,2}$"
    elseif regtype="score" then
        reg.pattern="^[\d]{"&min&","&max&"}\.[\d]{1}$"
    elseif regtype="coordinate" then
        reg.pattern="^[-]?[\d]{0,3}\.?[\d]{0,4}$"
    elseif regtype="dob" then
        reg.pattern="^([\d]{1,2}/[\d]{1,2}/[\d]{4})?$"
    elseif regtype="gamedate" then   
        reg.pattern="\d{2}?/\d{2}?/\d{4}?|TBA|TBA.??\d{4}?"
    end if
    validation_checks=reg.test(inputStr)           
end function

Our function takes 4 input parameters. An inputstring (your form data or querystring etc), regtype (the pattern you want to check against from the if statements), and a min and max (not needed for all of the validation checks, in which case null can be sent). Min and Max are useful where a field may not be required, but if something is entered you want to check it's right...I.E. a telephone number may not be a requirement, but if you enter something it needs to be digits only and no more than 11 digits, so you'd send a min of 0 and a max of 11.

And thats it basically! By calling this function on all your collected data you can quickly verify data input integrity, and better still because its a function you can re-use it over and over again.

Check back for more input validation techniques soon! 

A weblog (blog) is an online journal you can use to share thoughts, ideas, gripes, project status, or anything else you want. Blogs allow you to be a contributor rather than just a bystander.

Postings are arranged chronologically and can be categorized depending upon how the administrator has configured the system. You can view a post by clicking on the title from the home page where all users' posts are collectively shown. Once viewing a blog you can read other posts by that person or provide comments on postings.

Creating new posts is quick and easy. If you have the ability to post you should see a link (usually on the left) on your weblog's home page: new post. Clicking on this link takes you into your blogs administration pages for creating new posts.

If you don't have the ability to post, contact the site administrator and ask for your own blog.

Happy Blogging!